Sandboxie Support

Code: Select all

/*
*** UNSANDBOXED ***
Save script as BenchmarkIE.ahk
Unregistered Sandboxie users,
save script as DefaultBox.ahk
Drag & Drop onto AutoHotkey.exe
*** UNSANDBOXED ***
*/

#SingleInstance off

Global WCHAR:=2
Global TCHAR:=A_IsUnicode?WCHAR:1
Global MAX_PATH:=(32767*TCHAR)+TCHAR

;Global _ScriptName:=RegExReplace(A_ScriptName,"i)[^0-9A-Z_]","_")
Global _ScriptName:=RegExReplace(A_ScriptName,"i)([0-9A-Z_]+).*","$1")

Global _AhkPath
if(A_IsCompiled)
	_AhkPath="%A_ScriptFullPath%"
else
	_AhkPath="%A_AhkPath%" "%A_ScriptFullPath%"

params=%0%
Loop,%0%
	param%A_Index%:=%A_Index%

Process,Exist
Global _ScriptPID:=ErrorLevel

if(param1=="BOXED")
{
	Global BOXED:=true
	
	if(!DllCall("AttachConsole","UInt",param2))
		MsgBox,AttachConsole()	error`n%A_LastError%
	
	;SetTitleMatchMode,RegEx
	SetTitleMatchMode,3
	SetTitleMatchMode,Fast
	DetectHiddenWindows,Off
	
	if param3 contains BenchmarkIE
	{
		Target=%ProgramFiles%\Internet Explorer\iexplore.exe
		;SetBatchLines,-1
		Loop,3
		{
			StartTime:=A_TickCount
			Run,%Target%,,Max
			;Run,%Target%,,Min
			;Run,%Target%,,Hide
			WinWait,ahk_class IEFrame
			ElapsedTime:=A_TickCount-StartTime
			Console("ECHO	" ElapsedTime " ms")
			WinClose
			WinWaitClose
		}
	}
	else if param3 contains BenchmarkToolTip
	{
		;SetBatchLines,-1
		Loop,3
		{
			StartTime:=A_TickCount
			Loop,1000
			{
				ToolTip,%A_Index%,%X%,%Y%
			}
			ElapsedTime:=A_TickCount-StartTime
			Console("ECHO	" ElapsedTime " ms")
		}
	}
	
	ExitApp
}

if(false&&!A_IsAdmin)
{
	Run,*RunAs %_AhkPath%,%A_ScriptDir%,UseErrorLevel
	ExitApp
}

DllCall("AllocConsole")
Console()

if(A_PtrSize==4&&A_Is64bitOS)
	Global Sandboxie32:="\32"

Global SbieDll,SbieExe,SbieIni

SbiePathCandidates:=[]
SbiePathCandidates.Insert(Object("RootKey","HKEY_LOCAL_MACHINE","SubKey","SYSTEM\CurrentControlSet\Services\SbieDrv","ValueName","ImagePath"))
SbiePathCandidates.Insert(Object("RootKey","HKEY_LOCAL_MACHINE","SubKey","SYSTEM\CurrentControlSet\Services\SbieSvc","ValueName","ImagePath"))
SbiePathCandidates.Insert(Object("RootKey","HKEY_LOCAL_MACHINE","SubKey","SYSTEM\CurrentControlSet\Services\EventLog\System\SbieDrv","ValueName","EventMessageFile"))
SbiePathCandidates.Insert(Object("RootKey","HKEY_LOCAL_MACHINE","SubKey","SYSTEM\CurrentControlSet\Services\EventLog\System\SbieSvc","ValueName","EventMessageFile"))
SbiePathCandidates.Insert(Object("RootKey","HKEY_LOCAL_MACHINE","SubKey","SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\Sandboxie","ValueName","DisplayIcon"))
SbiePathCandidates.Insert(Object("RootKey","HKEY_CURRENT_USER","SubKey","Software\Microsoft\Windows\CurrentVersion\Run","ValueName","SandboxieControl"))

For IntKey,SbiePathCandidate in SbiePathCandidates
{
	RegRead,OutputVar,% SbiePathCandidate.RootKey,% SbiePathCandidate.SubKey,% SbiePathCandidate.ValueName
	StringReplace,OutputVar,OutputVar,",,All
	StringReplace,OutputVar,OutputVar,\??\
	SplitPath,OutputVar,,OutDir
	SbieDll:=OutDir Sandboxie32 "\SbieDll.dll"
	SbieExe:=OutDir "\Start.exe"
	SbieIni:=OutDir "\SbieIni.exe"
	if(FileExist(SbieDll)&&FileExist(SbieExe)&&FileExist(SbieIni))
	{
		happy:=true
		break
	}
}

try
{
	if(!happy)
		throw
	
	Global hSbieDll:=DllCall("LoadLibrary","Str",SbieDll,"UPtr")
	Global SbieApi:={EnumBoxes:0,EnumProcessEx:0,QueryBoxPath:0}
	For Proc,Address in SbieApi
	{
		SbieApi[Proc]:=DllCall("GetProcAddress","UPtr",hSbieDll,"AStr","SbieApi_" Proc,"UPtr")
		if(!SbieApi[Proc])
			throw
	}
	
	Global boxed_pids
	VarSetCapacity(boxed_pids,4*512)
}
catch
{
	if(!happy)
		MsgBox,Not happy!
	else
		MsgBox,Unhandled exception.
	
	ExitApp
}

Global SandboxTerminated

Target="%SbieIni%" set %_ScriptName% Enabled y
RunWait(false,Target)

Gui,1:+AlwaysOnTop +Caption +OwnDialogs -Resize 

Global OpenWinClass
Gui,1:Add,Text,W300 +BackgroundTrans,OpenWinClass=
Gui,1:Add,Edit,W300 VOpenWinClass GOpenWinClass -Wrap
Gui,1:Add,Button,W300 GAsterisk,*
Gui,1:Add,Button,W300 GTerminate,Terminate [%_ScriptName%] Programs
Gui,1:Add,Button,W300 GBenchmarkIE,Benchmark IExplore`n(timed from process create to moment window visible)
Gui,1:Add,Button,W300 GBenchmarkToolTip,Benchmark ToolTips`n(keeping mouse still versus movement affects results)
Gui,1:Show,AutoSize
return

GuiClose:
Gosub,Terminate
ExitApp

OpenWinClass:
Gui,1:Submit,NoHide
return

Asterisk:
GuiControl,,OpenWinClass,% OpenWinClass?"":"*"
return

Terminate:
Terminate(false)
return

BenchmarkIE:
BenchmarkToolTip:
Benchmark(A_ThisLabel)
return

Terminate(silent:=true)
{
	Target="%SbieExe%" /box:%_ScriptName% /terminate
	return SandboxTerminated:=RunWait(silent,Target)==0
}

Benchmark(_ThisLabel)
{
	static recursive:=0
	if(recursive>0)
		return
	++recursive
	
	try
	{
		Gui,1:+OwnDialogs
		
		_OpenWinClass:=OpenWinClass
		
		Console("ECHO [" _ScriptName "] " _ThisLabel)
		
		if(!Terminate())
			throw "Failed to Terminate Programs."
		SandboxTerminated:=false
		
		Target="%SbieIni%" set %_ScriptName% OpenWinClass "%_OpenWinClass%"
		if(RunWait(true,Target))
			throw "Failed to set OpenWinClass=" _OpenWinClass
		
		Console("ECHO [" _ScriptName "] OpenWinClass=" _OpenWinClass)
		
		Target="%SbieExe%" /box:%_ScriptName% %_AhkPath% BOXED %_ScriptPID% %_ThisLabel%
		;SetBatchLines,-1
		StartTime:=A_TickCount
		RunWait,%Target%
		;ExitCode()
		Loop
		{
			if(DllCall(SbieApi.EnumProcessEx,"WStr",_ScriptName,"UChar",FALSE,"UInt",-1,"UPtr",&boxed_pids,"Int"))
			{
				MsgBox,SbieApi_EnumProcessEx()	error
				break
			}
		}
		Until !NumGet(boxed_pids,"UInt")
		ElapsedTime:=A_TickCount-StartTime
		
		SetFormat,float,0.3
		Console("ECHO [" _ScriptName "] " (SandboxTerminated?"terminated":"finished") ". " "Waited " ElapsedTime/1000 " seconds.")
	}
	catch str
	{
		if(!StrLen(str))
			str:="Unhandled exception."
		Console("ECHO " str)
	}
	
	--recursive
}

ExitCode(silent)
{
	ExitCode:=ErrorLevel
	if(!silent)
		Console("ECHO (ExitCode " ExitCode ")")
	return ExitCode
}

RunWait(silent,Target,WorkingDir:="",Max_Min_Hide_UseErrorLevel:="",ByRef OutputVarPID:="")
{
	if(!silent)
		Console("ECHO " Target)
	RunWait,%Target%,%WorkingDir%,%Max_Min_Hide_UseErrorLevel%,OutputVarPID
	return ExitCode(silent)
}

Console(ByRef str:="")
{
	system("COLOR " (BOXED?"0E":"0F") "&TITLE " _ScriptName)
	if(str)
		system(str)
}

system(ByRef str)
{
	return DllCall("msvcrt\system","AStr",str,"Cdecl " "Int")
;	return DllCall("msvcr100\system","AStr",str,"Cdecl " "Int")
}

Code: Select all

	else if param3 contains BenchmarkIsWindowVisible
	{
		hWnd:=WinExist("ahk_class Shell_TrayWnd")
		SetBatchLines,-1
		Loop,3
		{
			StartTime:=A_TickCount
			Loop,10000
			{
				DllCall("IsWindowVisible","UPtr",hWnd)
			}
			ElapsedTime:=A_TickCount-StartTime
			Console("ECHO	" ElapsedTime " ms")
		}
	}

Code: Select all

Gui,1:Add,Button,W300 GBenchmarkIsWindowVisible,Benchmark IsWindowVisible

Code: Select all

BenchmarkIsWindowVisible:
Benchmark(A_ThisLabel)
return